Ethernet サーバー

Ethernetでサーバーとして動作するためのライブラリです。

EthernetServer()

概要
サーバーを作るためのコンストラクターです。
文法(例)
EthernetServer server(uint16_t port)
パラメータ
接続するポート

begin

概要
サーバーとしてクライアントからの接続待ちを開始します。
文法
server.begin()
パラメータ
なし
戻り値
なし

available

概要
サーバーに接続していて受信データのあるクライアントのオブジェクトを返します。
文法
server.available()
パラメータ
なし
戻り値
接続しているクライアントのオブジェクト。if文でオブジェクトが返されなければ、falseを返します。

write

概要
接続しているすべてのクライアントにデータを送信する。
文法
server.write(val)
server.write(buf, len)
パラメータ
val: 1バイトのデータ (byte or char)
buf: 複数バイトの配列データ (byte or char)
len: 配列データの長さ
戻り値
送ったバイト数。特に読む必要なし。

print

概要
接続しているすべてのクライアントにデータを送る。数字はそれぞれASCIIコードとしてデータを送る。例えば123は'1','2','3'として送られる。
文法
server.print(data)
server.print(data, BASE)
パラメータ
data: 送る文字列や数値
BASE(オプション): 基数(BYTE、BIN、DEC、HEX、OCT)
戻り値
送ったバイト数。あまり読む必要はない。

println

概要
接続しているすべてのクライアントに改行付きでデータを送る。数字はそれぞれASCIIコードとしてデータを送る。例えば123は'1','2','3'として送られる。
文法
server.println()
server.println(data)
server.println(data, BASE)
パラメータ
data: 送る文字列や数値
BASE(オプション): 基数(BYTE、BIN、DEC、HEX、OCT)
戻り値
送ったバイト数。あまり読む必要はない。

サンプルプログラム

サーバーサンプル。クライアントに5秒ごとにA0~A5の値を読んで返します。


#include <Arduino.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
 
// Initialize the Ethernet server library
// with the IP address and port you want to use
// (port 80 is default for HTTP):
EthernetServer server(80);
  
void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial.available()) ; // wait to press key
 
  // start the Ethernet connection and the server:
  Ethernet.begin(mac);
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}
 
void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br/ >");
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        }
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}